* ------------------------------------------------------------- *
       IDENTIFICATION DIVISION.
      * ------------------------------------------------------------- *
       PROGRAM-ID. DDLISTR.
       AUTHOR.     Abbydale Systems LLC.
      * ------------------------------------------------------------- *
       ENVIRONMENT DIVISION.
      * ------------------------------------------------------------- *
       INPUT-OUTPUT SECTION.
      * ------------------------------------------------------------- *
       DATA DIVISION.
      * ------------------------------------------------------------- *
       WORKING-STORAGE SECTION.
      * ------------------------------------------------------------- *
       01 WS-CURRENT-DATE-TIME.
          05 WS-CURRENT-DATE.
             10 WS-CURRENT-YEAR  PIC  9(4).
             10 WS-CURRENT-MONTH PIC  9(2).
             10 WS-CURRENT-DAY   PIC  9(2).
          05 WS-CURRENT-TIME.
             10 WS-CURRENT-HOUR  PIC  9(2).
             10 WS-CURRENT-MIN   PIC  9(2).
             10 WS-CURRENT-SEC   PIC  9(2).
             10 WS-CURRENT-MS    PIC  9(2).
       01  TCB-ADDRESS-POINTER.
           05  TCB-ADDR-POINTER USAGE IS POINTER.
       01  TIOT-SEG-POINT.
           05  TIOT-SEG-POINTER USAGE IS POINTER.
           05  TIOT-SEG-PNT REDEFINES TIOT-SEG-POINTER
                 PIC S9(9) COMP.
       01  JFCB-POINT.
           05  JFCB-POINTER USAGE IS POINTER.
           05  JFCB-POINT-RED REDEFINES JFCB-POINTER.
               10  FILLER PIC X.
               10  JFCB-LOW-3 PIC X(3).
      * ------------------------------------------------------------- *
       LINKAGE SECTION.
      * ------------------------------------------------------------- *
       01  TCB-POINTER USAGE IS POINTER.
       01  TCB.
           05  FILLER    PIC X(12).
           05  TIOT-POINTER USAGE IS POINTER.
           05  FILLER    PIC X(164).
           05  TCBJSCBB  POINTER.
       01  TIOT-START.
          05 TIOCNJOB    PIC X(8).
          05 TIOCSTPN    PIC X(8).
          05 FILLER      PIC X(4).
          05 FILLER      PIC X(4).
       01  TIOT-SEG.
           05  TIO-LEN   PIC X.
           05  FILLER    PIC X(3).
           05  DD-NAME   PIC X(8).
           05  JFCB-ADDR PIC X(3).
       01  JFCB.
           05  FILLER    PIC X(16).
           05  DS-NAME   PIC X(44).
       01  JSCB.
           05  FILLER    PIC X(316).
           05  SSIBPNTR  POINTER.
           05  FILLER    PIC X(40).
           05  JSCBPGNM  PIC X(8).
       01  CVT-ADRS                     USAGE IS POINTER.
       01 PSA.
          05 FILLER      PIC X(16).
          05 CVTADDR     POINTER.
          05 FILLER      PIC X(520).
          05 PSATOLD     POINTER.
       01 CVT.
          05 FILLER      PIC X(140).
          05 ECVTPNTR    POINTER.
       01 ECVT.
          05 FILLER      PIC X(344).
          05 ECVTLPAR    PIC X(8).
       01 SSIB.
          05 FILLER      PIC X(12).
          05 SSJOBNUM    PIC X(8).
      *
           EJECT
      * ------------------------------------------------------------- *
       PROCEDURE DIVISION.
      * ------------------------------------------------------------- *
       A-MAIN SECTION.
      * ------------------------------------------------------------- *
      *    Address PSA
           SET ADDRESS OF PSA TO NULL
      *    Address CVT
           SET ADDRESS OF CVT TO CVTADDR.
      *    Address TCB
           SET ADDRESS OF TCB TO PSATOLD
      *    Address TIOT
           MOVE X'0000021C' TO TCB-ADDRESS-POINTER.
      *    Address ECVT
           SET ADDRESS OF TCB-POINTER TO TCB-ADDR-POINTER.
           SET ADDRESS OF TCB TO TCB-POINTER.
           SET ADDRESS OF TIOT-START TO TIOT-POINTER.
           SET ADDRESS OF ECVT TO ECVTPNTR.
           SET ADDRESS OF JSCB TO TCBJSCBB.
           SET ADDRESS OF SSIB TO SSIBPNTR.
           SET TIOT-SEG-POINTER TO TIOT-POINTER.
           ADD 24 TO TIOT-SEG-PNT.
           SET ADDRESS OF TIOT-SEG TO TIOT-SEG-POINTER.
           MOVE LOW-VALUES TO JFCB-POINT.
           MOVE FUNCTION CURRENT-DATE TO WS-CURRENT-DATE-TIME
           DISPLAY 'Job Details'.
           DISPLAY '==========='.
           DISPLAY ' '
           DISPLAY 'Job Name        : ' TIOCNJOB   .
           DISPLAY 'Job Number      : ' SSJOBNUM   .
           DISPLAY 'Running on LPAR : ' ECVTLPAR   .
           DISPLAY 'Program Name    : ' JSCBPGNM   .
           DISPLAY ' '.
           DISPLAY '                 DDNAME   Dataset Name'.
           DISPLAY '                 -------- ------------'.
           PERFORM UNTIL TIO-LEN = LOW-VALUES
              MOVE JFCB-ADDR TO JFCB-LOW-3
              SET ADDRESS OF JFCB TO JFCB-POINTER
              DISPLAY '                 ' DD-NAME ' ' DS-NAME
              ADD 20 TO TIOT-SEG-PNT
              SET ADDRESS OF TIOT-SEG TO TIOT-SEG-POINTER
           END-PERFORM.
       A-MAIN-END.
           DISPLAY ' '.
           DISPLAY 'Jobname - ' TIOCNJOB ' ended.'.
           DISPLAY ' '.
           DISPLAY 'Copyright - Abbydale Systems LLC. 2017 - '
              WS-CURRENT-YEAR.
           STOP RUN.
      * ------------------------------------------------------------- *
      *                  End of program
      * ------------------------------------------------------------- *